MPL Model Library MPL Model Library



DorianAuto, Example 6, Winston

   {  Exmpl9.2-6_DorianAuto.mpl  }

   {  Winston, Operations Research, Applications and Algorithms, 4th ed.  }

   {  Chapter 9.2,  Example 6,  Either Or (MIP),  Size: 8x6,  Page 488  }


TITLE    
    DorianAuto;

INDEX
    cartype := (Compact,Midsize,Large);

DATA
    Profit[cartype] := (2000,3000,4000);
    SteelReq[cartype] := (1.5,  3,  5);
    LaborReq[cartype] := ( 30, 25, 40);
    AvailLabor    := 60000;
    AvailSteel    := 6000;
    MinProduction := 1000;
    M[cartype]    := (2000,2000,1200);

VARIABLE
    Produce[cartype];

BINARY VARIABLES
    ChooseType[cartype];
   
MODEL

    MAX TotalProfit = SUM(cartype: Profit * Produce);
                
SUBJECT TO

    UpperProdLimit[cartype] -> UPL:
        
        Produce <= M * ChooseType;
   
    MinProdLimit[cartype] -> MPL: 
   
        MinProduction - Produce <= M * (1 - ChooseType);

    LaborLimit -> LBL:

        SUM(cartype: Produce * LaborReq) <= AvailLabor;   

    SteelLimit -> STL:

        SUM(cartype: Produce * SteelReq) <= AvailSteel;
 
END
















Return to MPL Model Library