MPL Model Library MPL Model Library



JCNickles, Example 4, Winston


   {  Exmpl9.2-4_JCNickles.mpl  }

   {  Winston, Operations Research, Applications and Algorithms, 4th ed.  }

   {  Chapter 9.2,  Example 4,  Lockbox (MIP),  Size: 5x6,  Page 483  }


TITLE    
    JCNickles;

INDEX
    region := (West,Midwest,East,South);
    city   := (LA,Chicago,NYC,Atlanta);
    
DATA
    Payment[region] := 10000 * (7, 5, 6, 4);
    AnnualCost := 50000;
    PaymentTime[region,city] := (2, 6, 8, 8, 
                                 6, 2, 5, 5,
                                 8, 5, 2, 5,
                                 8, 5, 5, 2);
    AnnualInterest := 20%;
    AnnualLostInterest[region,city] := AnnualInterest * Payment * PaymentTime;

BINARY VARIABLES
    Operate[city];
    Send[region,city];

MODEL

    MIN TotalCost = SUM(region,city: Send * AnnualLostInterest) + SUM(city: Operate * AnnualCost); 
                
SUBJECT TO

    SingleCityPayment[region] -> SCP:

        SUM(city: Send) = 1;

    OperateLockBox[region,city] -> OLB:
      
        Send <= Operate;

END













Return to MPL Model Library