MPL Model Library MPL Model Library



PowerCo, Example 1, Winston


    {  Exmpl8.2_1PowerCo.mpl  }

    {  Winston, Operations Research, Applications and Algorithms, 3rd ed.  }

    {  Chapter 4.2,  Example 1, Shortest Path,  Size: 6x7,  Page 414 } 


TITLE
    PowerCo;

INDEX
    node := 1..6;
    node2 := node;    
    node3 := node;

DATA
    DistApart[node,node2]  := [1,2,4,
                               1,3,3,
                               2,4,3,
                               2,5,2,
                               3,5,3,
                               4,6,2,
                               5,6,2];
    NetFlow := 1;
    
VARIABLE
    Route[node,node2] WHERE (DistApart > 0);
 
MODEL

    MIN TotalDistance = SUM(node,node2: Route * DistApart);

SUBJECT TO
    
    StartFlow[node=1]:       SUM(node2: Route) = NetFlow;

    FlowBalance[node=2..5]:  SUM(node2: Route[node:=node2,node2:=node]) 
                           = 
                             SUM(node2: Route);

    EndFlow[node=6]:         SUM(node2: Route[node:=node2,node2:=node]) =  NetFlow;
    
END





Return to MPL Model Library