MPL Model Library MPL Model Library



Rylon Corp.,  Example 3.9-11-9,  Winston
   {  Exmpl3.9-11_Rylon.mpl  }

   {  Winston, Operations Research, Applications and Algorithms, 3rd ed.  }

   {  Chapter 3.9,  Example 11,  Production Process,  Size: 5x4,  Page 95  }


TITLE
    RylonCorp;

INDEX
    perfume  := (Brute, Chanele);
    type     := (Regular, Luxury);

DATA
    RawMatCost            :=  3.00;            [$/lb]
    RawMatYield[perfume]  :=  (3, 4);          [oz/lb]
 
    LabTimeRaw            :=  1;               [Hour/lb]
    LabTimeLux[perfume]   :=  (3, 2);          [Hour/oz]

    Price[perfume, type]  := (7, 18,    
                              6, 14);          [$/oz]

    ProcessCost[perfume]  := (4, 4);           [$/oz]

    LabTimeAvail          := 6000;
    RawMatAvail           := 4000;

VARIABLES
    Sales[perfume, type];                      [oz]
    RawMatPurchased;                           [lb]

MACROS
    TotalRevenue     := SUM(perfume, type:  Price * Sales);
    TotalProcessCost := SUM(perfume,type=Luxury:  ProcessCost * Sales);
    TotalRawMatCost  := RawMatCost * RawMatPurchased;

MODEL

    MAX TotalProfit = TotalRevenue - TotalProcessCost - TotalRawMatCost;

SUBJECT TO

    RawMatLimit: 

        RawMatPurchased <= RawMatAvail;


    LabTimeLimit: 
     
        LabTimeRaw * RawMatPurchased 

      + SUM(perfume,type=Luxury: LabTimeLux * Sales)  <=  LabTimeAvail; 


    MaterialBalance[perfume]:

        SUM(type: Sales) = RawMatYield * RawMatPurchased;

END




Return to MPL Model Library