MPL Model Library MPL Model Library



Nori and Leets, Example 3.4-3, Hillier and Lieberman


   {  Exmpl_3.4-3_NoriAndLeets.mpl  }

   {  Hillier and Lieberman, Introduction to Operations Research, 7th ed.  }

   {  Chapter 3.4,  Example 3,  Blending/Air Pollution,  Size: 3x6,  Page 50  }


TITLE
    NoriLeetsAirPollution;

INDEX
    pollutant := (Particulates, SulfurOxides, Hydrocarbons);
    furnace   := (Blast, OpenHearth);
    abatement := (TallerSmokestacks, Filters, BetterFuels);

DATA
    RequiredReduction[pollutant] := (60, 150, 125);

    ReducedEmissionRate[pollutant, abatement, furnace] :=

       (12,   9,   25,  20,   17,  13,
        35,  42,   18,  31,   56,  49,
        37,  53,   28,  24,   29,  20);

    AnnualCost[abatement, furnace] := 

        (8,  10,
         7,   6,
        11,   9);

VARIABLES
    UseMethod[abatement, furnace];

MODEL

    MIN  TotalCost = SUM(abatement, furnace: AnnualCost * UseMethod);

SUBJECT TO
    EmissionReduction[pollutant] :

       SUM(furnace, abatement: ReducedEmissionRate * UseMethod) >= RequiredReduction;

BOUNDS
    UseMethod  <=  1;

END



Return to MPL Model Library