# MOLPg.mod
# Original AMPL coding by Sven Leyffer, Argonne National Laboratory
#
# A generic MOLP (matrices are upper case; note transpose!)
#
#	minimize   C^T x
#	subj. to   A^T x <= b
#
# for data files, see ...
# 
# filename		reference
# ------------------------------------------------------------
# MOLPg-001.dat		[Steu:86] p. 411, Exercise 13-4C 
# MOLPg-002.dat		[Steu:86] p. 415, Exercise 13-14C
# MOLPg-003.dat		[Steu:86] p. 416, Exercise 13-15C
# 			... there are many more MOLPs in there!
# ------------------------------------------------------------
# References:
# ~~~~~~~~~~
# [Steu:86]	R.E. Steuer, Multiple Criteria Optimization: 
#		Theory, Computation and Applications, John 
#		Wiley, 1986, New York.
# ------------------------------------------------------------

# ... problem dimensions & index sets
param n >= 1, integer;	# ... number of variables
param m >= 1, integer;	# ... number of constraints
param p >= 1, integer;	# ... number of objectives
set N := 1..n;	
set M := 1..m;
set P := 1..p;

# ... problem data
param C{P,N};				# ... objective gradients
param A{M,N};				# ... constraint Jacobian
param b{M};				# ... upper bounds on A^T x

var x{N} >= 0;				# ... variables

# ... objective functions
minimize  f{pp in P}: -sum{i in N} C[pp,i]*x[i];

subject to

   # ... linear constraints
   lin{j in M}: sum{i in N} A[j,i]*x[i] <= b[j];